La fonction DATEDIF(pour les calculs d'âge) (voir le site de Laurent Longre sur DATEDIF fait partie des fonctions masquées d'Excel. Elle n'est pas référencée par l'aide en ligne. Elle est pourtant bien commode…
DATEDIF permet de calculer la différence entre deux dates en années, mois et jours.
Syntaxe : =DATEDIF ( Date1 ; Date2 ; Intervalle )
Cette fonction renvoie la différence entre Date1 et Date2 (Date2 >= Date1) selon l'argument Intervalle, qui peut prendre les valeurs suivantes :
"y" : différence en années
"m" : différence en mois
"d" : différence en jours
"ym" : différence en mois, une fois les années soustraites
"yd" : différence en jours, une fois les années soustraites
"md" : différence en jours, une fois les années et les mois soustraits
Exemple : =DATEDIF ( "5/4/1990" ; "15/8/99" ; Intervalle )
renvoie les valeurs suivantes selon la valeur de l'argument Intervalle :
"y" : 9 (ans)
"m" : 112 (mois)
"d" : 3419 (jours)
"ym" : 4 (mois restants, une fois les 9 ans soustraits)
"yd" : 132 (jours restants, une fois les 9 ans soustraits)
"md" : 10 (jours restants, une fois les 112 mois soustraits)
La fonction DATEDIF peut être en particulier utilisée pour calculer des âges.
Par exemple, si la cellule A1 contient une date de naissance et la cellule B1 la date du jour :
- Âge en années simples :
=DATEDIF(A1;B1;"y") & SI(DATEDIF(A1;B1;"y")>1;" ans";" an")
- Âge en années et mois :
=DATEDIF(A1;B1;"y") & SI(DATEDIF(A1;B1;"y")>1;" ans, ";" an, ") & DATEDIF(A1;B1;"ym") & " mois"
- Âge en années, mois et jours :
=DATEDIF(A1;B1;"y") & SI(DATEDIF(A1;B1;"y")>1;" ans, ";" an, ") & DATEDIF(A1;B1;"ym") & " mois, "
& DATEDIF(A1;B1;"md") & SI(DATEDIF(A1;B1;"md")>1;" jours";" jour")